IoT (Internet of Things) project of Temperature, Pressure, and Altitude measurement using Pressure sensor BMP180 and Arduino device

In this project, we are going to build a temperature, pressure, and altitude measuring system. In this project, we will use atmospheric pressure sensor model BM 180 to detect temperature, atmospheric pressure, and altitude, Arduino device, and 16 X 4 characters LCD to display the calculated temperature, pressure, and altitude.

Hardware requirements

Arduino UNO board
USB cable connector for Arduino device
Pressure Sensor BMP180
16 X 4 Character LCD Display
Project Board
Jumper wires (male to female, male to male)

Software requirement

Arduino software IDE

The working principle of Pressure Sensor BMP180

The pressure sensor BMP180 consists of a piezo-resistive sensor, an analog and digital converter, control unit with E2PROM and a serial I2C interface. It delivers the contributed values of temperature, atmospheric pressure, and altitude. The microcontroller of the sensor device sends the start sequence to measure temperature, pressure, and altitude. The values of temperature, pressure, and altitude are read over 16 X 4 characters LCD.

The calculated temperature, pressure, and altitude are measured in ℃ (degree celsius), hPa (hector Pascal) and feet respectively. In this case, the rate of measuring temperature, atmospheric pressure and altitude is once per second.

The altitude and pressure are inversely proportional to each other. When the altitude increases, pressure goes down and when altitude decreases it leads to an increase in atmospheric pressure.

IoT project of Temperature, Pressure, and Altitude measurement using Pressure sensor BMP180 and Arduino device

Write an Arduino program to measure temperature, pressure, and altitude using pressure sensor BMP180, Arduino and character LCD.

#include <LiquidCrystal.h>
LiquidCrystal lcd(13, 12, 11, 10, 9, 8);//RS,EN,D4,D5,D6,D7
#include <SFE_BMP180.h>
#include <Wire.h>
//create an SFE_BMP180 object, here called "pressure":
SFE_BMP180 pressure;
#define ALTITUDE 222.0 // altitude of Delhi in meters
void setup(){
  Serial.begin(9600);
  Serial.println("BMP180 Measurements");
  lcd.begin(20, 4);
  lcd.setCursor(0, 0);
  lcd.print("BMP180 Measurements");
  lcd.setCursor(0, 1);
  lcd.print(" 1. Temperature");
  lcd.setCursor(0, 2);
  lcd.print(" 2. Pressure");
  lcd.setCursor(0, 3);
  lcd.print(" 3. Altitude");
  delay (5000);
  lcd.clear();//clear display
  // initialize the sensor (it is important to get calibration values stored on the device).
  if (pressure.begin())
  Serial.println("BMP180 init success");
  else{
    // oops, something went wrong, this is usually a connection problem,
      // see the comments at the top of this sketch for the proper connections.
    Serial.println("BMP180 init fail\n\n");
    while(1); // pause forever.
  }
}
void loop(){
  char status;
  double T,P,p0,a;
  // loop here getting pressure readings every 10 seconds.
    // if you want sea-level-compensated pressure, as used in weather reports,
    // you need to find dinamically altitude of place.
    // here, we are using constant called ALTITUDE in this sketch:
  Serial.println();
  Serial.print("provided altitude: ");
  lcd.setCursor(0, 0);
  lcd.print("Altitude: ");
  Serial.print(ALTITUDE,0);
  Serial.print(" meters, ");
  Serial.print(ALTITUDE*3.28084,0);
  lcd.print(ALTITUDE*3.28084,0);
  Serial.println(" feet");
  lcd.print(" ft");
  // start a temperature measurement:
    // if request is successful, the number of ms to wait is returned.
    // if request is unsuccessful, 0 is returned.
  status = pressure.startTemperature();
  if (status != 0){
    // wait for the measurement to complete:
    delay(status);
    // retrieve the completed temperature measurement:
      // note that the measurement is stored in the variable T.
      // function returns 1 if successful, 0 if failure.
    status = pressure.getTemperature(T);
    if (status != 0){
      // Print out the measurement:
      Serial.print("temperature: ");
      Serial.print(T,2);
      Serial.print(" deg C, ");
      Serial.print((9.0/5.0)*T+32.0,2);
      Serial.println(" deg F");
      lcd.setCursor(0, 1);
      lcd.print("Temperature: ");
      lcd.print(T,2);
      lcd.print(" C ");
      // start a pressure measurement:
          // the parameter is the oversampling setting, from 0 to 3 (highest res, longest wait).
          // if request is successful, the number of ms to wait is returned.
          // if request is unsuccessful, 0 is returned.
      status = pressure.startPressure(3);
      if (status != 0){
        // wait for the measurement to complete:
        delay(status);
            // Retrieve the completed pressure measurement:
            // Note that the measurement is stored in the variable P.
            // Note also that the function requires the previous temperature measurement (T).
            // (If temperature is stable, you can do one temperature measurement for a number of pressure measurements.)
            // Function returns 1 if successful, 0 if failure.
        status = pressure.getPressure(P,T);
        if (status != 0){
          // print out the measurement:
          Serial.print("absolute pressure: ");
          Serial.print(P,2);
          Serial.print(" mb, ");
          Serial.print(P*0.0295333727,2);
          Serial.println(" inHg");
          lcd.setCursor(0, 2);
          lcd.print("Abs. Pr.: ");
          lcd.print(P*0.0295333727,2);
          lcd.print(" inHg");
            // The pressure sensor returns absolute pressure, which varies with altitude.
                // To remove the effects of altitude, use the sea level function and your current altitude.
                // This number is commonly used in weather reports.
                // Parameters: P = absolute pressure in mb, ALTITUDE = current altitude in m.
                // Result: p0 = sea-level compensated pressure in mb
          p0 = pressure.sealevel(P,ALTITUDE); // we are at 222 meters (Delhi)
          Serial.print("relative (sea-level) pressure: ");
          Serial.print(p0,2);
          Serial.print(" mb, ");
          Serial.print(p0*0.0295333727,2);
          Serial.println(" inHg");
          lcd.setCursor(0, 3);
          lcd.print("Rel. Pr.: ");
          lcd.print(p0*0.0295333727,2);
          lcd.print(" inHg");
          // On the other hand, if you want to determine your altitude from the pressure reading,
          // use the altitude function along with a baseline pressure (sea-level or other).
          // Parameters: P = absolute pressure in mb, p0 = baseline pressure in mb.
          // Result: a = altitude in m.
          a = pressure.altitude(P,p0);
          Serial.print("computed altitude: ");
          Serial.print(a,0);
          Serial.print(" meters, ");
          Serial.print(a*3.28084,0);
          Serial.println(" feet");
        }
        else 
          Serial.println("error retrieving pressure measurement\n");
      }
      else 
        Serial.println("error starting pressure measurement\n");
    }
    else
      Serial.println("error retrieving temperature measurement\n");
  }
  else
    Serial.println("error starting temperature measurement\n");
  delay(5000); // Pause for 5 seconds.
}

Download the SFE_BMP180-master.zip file from https://github.com/LowPowerLab/SFE_BMP180

Add the SFE_BMP180-master zip file before compiling the above code otherwise, it generates an error SFE_BMP180.h: No such file or directory.

To add the zip file click Sketch > Include Library > Add .ZIP Library... and add your downloaded SFE_BMP180-master zip.